Posts: 357
Threads: 40
Joined: Jul 2012
Reputation:
4
Thanks, Al, but I'm not that kind of person. AaaaaHahahaaa
Posts: 9
Threads: 1
Joined: Jun 2020
Reputation:
0
10-01-2020, 02:28 PM
Hi, I have done some progress.
Code:
'-------WRITE BY QUARKQ PAWEL S.-------------------------------------------
Sub Main()
Begin Dialog SPROCKETDIALOG 50,47, 182, 74, "Sprocket Maker"
Text 4,10,65,12, "Number of Teetch"
TextBox 68,8,49,12, .IDD_Tn
Text 4,26,65,12, "Pitch of Chain"
TextBox 68,24,49,12, .IDD_P
Text 4,42,97,12, "Roler Diameter"
TextBox 68,40,49,12, .IDD_Rd
Text 4,58,97,12, "Roller Clearance"
TextBox 68,56,49,12, .IDD_Backlash
OKButton 136,15,37,12
CancelButton 136,40,37,12
End Dialog
Dim dlg As SprocketDialog
Dim ot As Double
Dim si As Double
Dim ti As Double
Dim s As Double
Dim t As Double
Dim x As Double
Dim y As Double
Dim K As Double
Dim d As Double
Dim xp As Double
Dim yp As Double
Dim a As Double
Dim b As Double
Dim c As Double
Dim r0 As Double
Dim r1 As Double
Dim xt12 As Double
Dim yt12 As Double
Dim xt34 As Double
Dim yt34 As Double
Dim xt56 As Double
Dim yt56 As Double
Dim xt78 As Double
Dim yt78 As Double
dcSetDrawingScale 1.0
dcSetDrawingUnits dcMillimeters
dcSetLineParms dcBLACK, dcSOLID, dcNORMAL
dcSetCircleParms dcBLACK, dcSOLID, dcNORMAL
dcSetPointParms dcRED, False
dlg.IDD_Tn = "18" 'Teetch number
dlg.IDD_P = "12.7" 'Pitch
dlg.IDD_Rd = "8.5" 'Roler circle
dlg.IDD_Backlash = "0.1"
Button = Dialog(dlg)
If Button = -1 Then
Sprock dlg.IDD_Tn,dlg.IDD_P,dlg.IDD_Rd,dlg.IDD_Backlash,0,0
dcViewAll
End If
End Sub
Sub Sprock(ByVal Tn As Double,ByVal P As Double,ByVal Rd As Double,ByVal BACKLASH As Double, ByVal cx As Double, ByVal cy As Double)
Pi=3.1415926535897932384626433832795028841971
Pr =(((P * Tn) / Pi) / 2 ) 'Pitch Diameter
W=(Pr+(Rd*0.5))-(Pr+(Rd*0.25))
dcSelectAll
dcEraseSelObjs
dcCreateLine 0, 0, 0, Pr+(Rd*0.5)
'dcCreateCircle 0, 0, Pr 'Pitch Diameter
'dcCreateCircle 0, 0, Pr+(Rd*0.25) 'Pitch Circumferen ce 25% of Roller Diameter
dcCreateCircle 0, Pr, (Rd+Backlash)/2 'Roler circle plus 0.15
dcCreateCircle 0, W/2+(Pr+(Rd*0.25)) ,W/2 'Little circle
dcSelectObjInBox -1, Pr+(Rd*0.25), 1,W/2+(Pr+(Rd*0.25))
dcSetSelectBase 0, 0
dcRotateSelObjs 360/Tn/2
dcSetSelCopyMode True
dcRotateSelObjs (360/Tn/2)*(Tn-1)*2
dcUnSelectAll
'circle big one
a=0 'x1 =
b=Pr 'y1 =
r0=((Rd+Backlash)/2) 'r1 =
s=0
t=(W/2)+(Pr+(Rd*0.25))
si=s*Cos(((360/Tn/2)*Pi)/180)-t*Sin(((360/Tn/2)*Pi)/180) 'X smaller circle center
ti=s*Sin(((360/Tn/2)*Pi)/180)+t*Cos(((360/Tn/2)*Pi)/180) 'Y smaller circle center
'dcCreatePoint si,ti
' circle 2 little one right
c=si *-1 'x2 =
d=ti 'y2 =
r1=(W/2) 'r0
xp=((c*r0)+(a*r1))/r0+r1
yp=((d*r0)+(b*r1))/r0+r1
xt56=(((r0^2*(xp-a))+r0*(yp-b)*Sqr((xp-a)^2+(yp-b)^2-r0^2))/((xp-a)^2+(yp-b)^2))+a
yt56=(((r0^2*(yp-b))-r0*(xp-a)*Sqr((xp-a)^2+(yp-b)^2-r0^2))/((xp-a)^2+(yp-b)^2))+b
xt78=(((r1^2*(xp-c))-r1*(yp-d)*Sqr((xp-c)^2+(yp-d)^2-r1^2))/((xp-c)^2+(yp-d)^2))+c
yt78=(((r1^2*(yp-d))+r1*(xp-c)*Sqr((xp-c)^2+(yp-d)^2-r1^2))/((xp-c)^2+(yp-d)^2))+d
dcCreateLine xt56,yt56,xt78,yt78 ' tangent line on right
dcSelectObjInBox xt56+0.2,yt56+0.2,xt78-0.2,yt78-0.2
dcSetSelCopyMode True
dcMirrorSelObjs 0, 0, 0, 2
dcUnSelectAll
dcCreateText -20, -5, 3, "Teeth="
dcCreateText -5, -5, 3, Tn
dcCreateText -20, -10, 3, "Pitch="
dcCreateText -7, -10, 3, P
dcCreateText -20, -15, 3, "Roller_D="
dcCreateText 1, -15, 3, Rd
End Sub
Try this. I have problem to trim circles, i can't find dctrim... or something..
Posts: 387
Threads: 54
Joined: Apr 2014
Reputation:
8
10-02-2020, 12:16 AM
(This post was last modified: 10-02-2020, 01:28 AM by AlwMVMO.)
You will have to use dcCreateCircleEx (cx, cy, xa, ya, xb, yb, hrad, wrad, angle, arrow)
This function creates a circle, arc, ellipse, or elliptical arc. cx and cy are the center,
xa/ya and xb/yb are the endpoints of an arc. If you are drawing a complete circle
(i.e. not an arc) then xa/ya and xb/yb should be the same point. If you are drawing
an arc it is drawn counterclockwise from xa/ya to xb/yb. hrad is the height radius,
and wrad is the width radius. If drawing a circle (i.e. not an ellipse) set hrad and
wrad to the same value. angle is the angle of the ellipse in degrees (it is ignored
for circles). arrow indicates which end of the arc segment should get an arrow
head. 1 is end A, and 2 is end B. The arrow value is only used if the line type is
set to an arrow line.
Return Value: True if successful, otherwise False.
Example:
Sub Main
dcCreateCircleEx 0, 0, 1.41, 1.41, 1.41, 1.41, 1, 2, 45, 0
End Sub
P.S. I noticed your the endpoints of your tangent lines are a little bit different than the endpoints that DeltaCad makes.
If you set the line and circle thickness to thin and then go into Options/Drawing Data... and set the Thin Line thickness to a smaller number like .005 you can see the mismatch.
Posts: 9
Threads: 1
Joined: Jun 2020
Reputation:
0
10-02-2020, 10:23 AM
(This post was last modified: 10-02-2020, 10:35 AM by quarkqq.)
Thanks AlwMVMO
I found mistake. Should be fine now.
Code:
'-------WRITE BY QUARKQ PAWEL S.-------------------------------------------
Sub Main()
Begin Dialog SPROCKETDIALOG 50,47, 182, 94, "Sprocket Maker"
Text 4,10,65,12, "Number of Teetch"
TextBox 68,8,49,12, .IDD_Tn
Text 4,26,65,12, "Pitch of Chain"
TextBox 68,24,49,12, .IDD_P
Text 4,42,97,12, "Roler Diameter"
TextBox 68,40,49,12, .IDD_Rd
Text 4,58,97,12, "Roller Clearance"
TextBox 68,56,49,12, .IDD_Backlash
Text 4,72,97,12, "Centre Hole_D"
TextBox 68,72,49,12, .IDD_j
OKButton 136,15,37,12
CancelButton 136,40,37,12
End Dialog
Dim dlg As SprocketDialog
Dim si As Double
Dim ti As Double
Dim s As Double
Dim t As Double
Dim x As Double
Dim y As Double
Dim d As Double
Dim xp As Double
Dim yp As Double
Dim a As Double
Dim b As Double
Dim c As Double
Dim r0 As Double
Dim r1 As Double
Dim xt56 As Double
Dim yt56 As Double
Dim xt78 As Double
Dim yt78 As Double
dcSetDrawingScale 1.0
dcSetDrawingUnits dcMillimeters
dcSetLineParms dcBLACK, dcSOLID, dcNORMAL
dcSetCircleParms dcBLACK, dcSOLID, dcNORMAL
dcSetPointParms dcRED, False
dlg.IDD_Tn = "18" 'Teetch number
dlg.IDD_P = "9.525" 'Pitch
dlg.IDD_Rd = "6.5" 'Roler circle
dlg.IDD_Backlash = "0.1"
dlg.IDD_j = "10"
Button = Dialog(dlg)
If Button = -1 Then
Sprock dlg.IDD_Tn,dlg.IDD_P,dlg.IDD_Rd,dlg.IDD_Backlash,dlg.IDD_j,0,0
dcViewAll
End If
End Sub
Sub Sprock(ByVal Tn As Double,ByVal P As Double,ByVal Rd As Double,ByVal BACKLASH As Double,ByVal j As Double, ByVal cx As Double, ByVal cy As Double)
Pi=3.1415926535897932384626433832795028841971
Pr =(P/Sin((180/Tn)*pi/180))/2 '(((P * Tn) / Pi) / 2 ) 'Pitch Diameter
W=(Pr+(Rd*0.35))-(Pr+(Rd*0.25))
dcSelectAll
dcEraseSelObjs
dcCreateLine 0, 0, 0, Pr+(Rd*0.35)
'dcCreateCircle 0, 0, Pr 'Pitch Diameter
'dcCreateCircle 0, 0, Pr+(Rd*0.25) 'Pitch Circumferen ce 25% of Roller Diameter
'dcCreateCircle 0, Pr, (Rd+Backlash)/2 'Roler circle plus 0.1
'dcCreateCircle 0, W/2+(Pr+(Rd*0.25)) ,W/2 'Little circle
'dcCreateCircleEx 0, W/2+(Pr+(Rd*0.25)), 90, -90, 0, 90, w/2, w/2, 0, 0 'Little circle
dcCreateCircle 0, 0, j/2
dcSelectObjInBox -1, Pr+(Rd*0.25), 1,W/2+(Pr+(Rd*0.25))
dcSetSelectBase 0, 0
dcRotateSelObjs 360/Tn/2
dcSetSelCopyMode True
dcRotateSelObjs (360/Tn/2)*(Tn-1)*2
dcMirrorSelObjs 0, 0, 0, 2
dcUnSelectAll
s=0
t=(W/2)+(Pr+(Rd*0.25))
si=s*Cos(((360/Tn/2)*Pi)/180)-t*Sin(((360/Tn/2)*Pi)/180) 'X smaller circle center
ti=s*Sin(((360/Tn/2)*Pi)/180)+t*Cos(((360/Tn/2)*Pi)/180) 'Y smaller circle center
'little circle end point 2
m=0
n=Pr+(Rd*0.35)
mi=m*Cos(((360/Tn/2)*Pi)/180)-n*Sin(((360/Tn/2)*Pi)/180) 'X smal circle center
ni=m*Sin(((360/Tn/2)*Pi)/180)+n*Cos(((360/Tn/2)*Pi)/180) 'Y smal circle center
'circle big one
a=0 'x1 =
b=Pr 'y1 =
r0=((Rd+Backlash)/2) 'r1 =
'circle 2 little one right
c=si *-1 'x2 =
d=ti 'y2 =
r1=(W/2) 'r0
xp=((c*r0)+(a*r1))/(r0+r1)
yp=((d*r0)+(b*r1))/(r0+r1)
xt56=(((r0^2*(xp-a))+r0*(yp-b)*Sqr((xp-a)^2+(yp-b)^2-r0^2))/((xp-a)^2+(yp-b)^2))+a
yt56=(((r0^2*(yp-b))-r0*(xp-a)*Sqr((xp-a)^2+(yp-b)^2-r0^2))/((xp-a)^2+(yp-b)^2))+b
xt78=(((r1^2*(xp-c))+r1*(yp-d)*Sqr((xp-c)^2+(yp-d)^2-r1^2))/((xp-c)^2+(yp-d)^2))+c
yt78=(((r1^2*(yp-d))-r1*(xp-c)*Sqr((xp-c)^2+(yp-d)^2-r1^2))/((xp-c)^2+(yp-d)^2))+d
dcCreateLine xt56,yt56,xt78,yt78 ' tangent line on right
dcSelectObjInBox xt56+0.2,yt56+0.2,xt78-0.2,yt78-0.2
dcSetSelCopyMode True
dcMirrorSelObjs 0, 0, 0, 2 'mirror line
dcUnSelectAll
'proba duzego na promien
dcCreateCircleEx 0, Pr, -xt56, yt56, xt56, yt56, (Rd+Backlash)/2, (Rd+Backlash)/2, 0, 0
dcCreateCircleEx si, ti, -xt78, yt78, mi, ni, W/2, W/2, 0, 0
dcSelectObjInBox si+0.1, ti, si+0.2,ti+30
dcSetSelCopyMode True
dcMirrorSelObjs 0, 0, 0, 2
dcUnSelectAll
dcSelectObjInBox -1, -1, 1, 1
dcEraseSelObjs
dcUnSelectAll
dcSelectAll
dcSetSelectBase 0, 0
For z=0 to Tn-1
dcRotateSelObjs 360/Tn
dcSetSelCopyMode True
Next z
dcUnSelectAll
dcSetTextParms dcRED, “Arial”, “Normalny”, 0,2,0, 0.1, 0
dcCreateText 0, -5, 3, "Teeth="
dcCreateText 2.4, -5, 3,Tn
dcCreateText 0, -6, 3, "Pitch="
dcCreateText 2.2, -6, 3,P
dcCreateText 0, -7, 3, "Roller_D="
dcCreateText 3.6, -7, 3.5,Rd
dcCreateText 0, -8, 3, "Pitch_D="
dcCreateText 3.3, -8, 4,Pr*2
dcCreateText 0, -9, 3, "Max_D="
dcCreateText 3, -9, 4,(Pr+(Rd*0.35))*2
End Sub
Posts: 357
Threads: 40
Joined: Jul 2012
Reputation:
4
10-02-2020, 12:09 PM
(This post was last modified: 10-02-2020, 07:39 PM by williamj.)
quarkqq,
That last version worked spot on for me.
I want to thank you for all of your hard work. And I want to thank AlwMVMO for his contribution as well.
The forum now has a brand spanking new macro!
Thanks again.
Posts: 387
Threads: 54
Joined: Apr 2014
Reputation:
8
10-03-2020, 02:18 AM
(This post was last modified: 10-03-2020, 02:42 AM by AlwMVMO.)
I made some improvements to the text at the end of the macro.
Code:
NL$ = Chr$(13) + Chr$(10)
SprText$ = "Teeth=" + Str$(Tn) + NL$
SprText$ = SprText$ + "Pitch=" + Str$(P) + NL$
SprText$ = SprText$ + "Roller_D=" + Str$(Rd) + NL$
SprText$ = SprText$ + "Pitch_D=" + Str$(Pr*2) + NL$
SprText$ = SprText$ + "Max_D=" + Str$((Pr+(Rd*0.35))*2)
dcCreateText 0, -5, 0, SprText$
I translated the comment 'proba duzego na promien', I got 'large test per radius'.
Posts: 357
Threads: 40
Joined: Jul 2012
Reputation:
4
Can there be a selection of either millimeters or inches?
Posts: 9
Threads: 1
Joined: Jun 2020
Reputation:
0
10-03-2020, 12:44 PM
(This post was last modified: 10-03-2020, 01:30 PM by quarkqq.
Edit Reason: improvements
)
Thanks for text improve AlwMVMO. It is much better now.
Inches for Williamj, but doesn't work propely, i have no idea why. I hope AlwMVMO will help.
Code:
''-------WRITE BY QUARKQ , AlwMVMO, Williamj -------------------------------------
Sub Main()
Begin Dialog SPROCKETDIALOG 50,47, 182, 114, "Sprocket Maker"
Text 4,10,65,12, "Number of Teetch"
TextBox 68,8,49,12, .IDD_Tn
Text 4,26,65,12, "Pitch of Chain"
TextBox 68,24,49,12, .IDD_P
Text 4,42,97,12, "Roler Diameter"
TextBox 68,40,49,12, .IDD_Rd
Text 4,58,97,12, "Roller Clearance"
TextBox 68,56,49,12, .IDD_Backlash
Text 4,74,97,12, "Centre Hole_D"
TextBox 68,74,49,12, .IDD_j
Text 4,90,97,12, "mm=1 inch=2"
TextBox 68,90,49,12, .IDD_k
OKButton 136,15,37,12
CancelButton 136,40,37,12
End Dialog
Dim dlg As SprocketDialog
Dim si As Double
Dim ti As Double
Dim s As Double
Dim t As Double
Dim x As Double
Dim y As Double
Dim d As Double
Dim xp As Double
Dim yp As Double
Dim a As Double
Dim b As Double
Dim c As Double
Dim r0 As Double
Dim r1 As Double
Dim xt56 As Double
Dim yt56 As Double
Dim xt78 As Double
Dim yt78 As Double
dcSetLineParms dcBLACK, dcSOLID, dcNORMAL
dcSetCircleParms dcBLACK, dcSOLID, dcNORMAL
dcSetPointParms dcRED, False
dlg.IDD_Tn = "18" 'Teetch number
dlg.IDD_P = "9.525" 'Pitch
dlg.IDD_Rd = "6.5" 'Roler circle
dlg.IDD_Backlash = "0.1"
dlg.IDD_j = "10"
dlg.IDD_k = "1"
Button = Dialog(dlg)
If Button = -1 Then
Sprock dlg.IDD_Tn,dlg.IDD_P,dlg.IDD_Rd,dlg.IDD_Backlash,dlg.IDD_j,dlg.IDD_k,0,0
dcViewAll
End If
End Sub
Sub Sprock(ByVal Tn As Double,ByVal P As Double,ByVal Rd As Double,ByVal BACKLASH As Double,ByVal j As Double,ByVal k As Double, ByVal cx As Double, ByVal cy As Double)
Pi=3.1415926535897932384626433832795028841971
Pr =(P/Sin((180/Tn)*pi/180))/2 '(((P * Tn) / Pi) / 2 ) 'Pitch Diameter
W=(Pr+(Rd*0.5))-(Pr+(Rd*0.25))
If(dcSelectAll) Then dcEraseSelObjs
dcSetDrawingScale 1.0
If k=1 Then
dcSetDrawingUnits dcMillimeters
ElseIf k=2 Then
dcSetDrawingUnits dcInches
ElseIf k>2 Then
k=1
End If
dcCreateLine 0, 0, 0, Pr+(Rd*0.5)
'dcCreateCircle 0, 0, Pr 'Pitch Diameter
'dcCreateCircle 0, 0, Pr+(Rd*0.25) 'Pitch Circumferen ce 25% of Roller Diameter
'dcCreateCircle 0, Pr, (Rd+Backlash)/2 'Roler circle plus 0.1
'dcCreateCircle 0, W/2+(Pr+(Rd*0.25)) ,W/2 'Little circle
'dcCreateCircleEx 0, W/2+(Pr+(Rd*0.25)), 90, -90, 0, 90, w/2, w/2, 0, 0 'Little circle
dcSelectObjInBox -1, Pr+(Rd*0.25), 1,W/2+(Pr+(Rd*0.25))
dcSetSelectBase 0, 0
dcRotateSelObjs 360/Tn/2
dcSetSelCopyMode True
dcRotateSelObjs (360/Tn/2)*(Tn-1)*2
dcMirrorSelObjs 0, 0, 0, 2
dcUnSelectAll
s=0
t=(W/2)+(Pr+(Rd*0.25))
si=s*Cos(((360/Tn/2)*Pi)/180)-t*Sin(((360/Tn/2)*Pi)/180) 'X smaller circle center
ti=s*Sin(((360/Tn/2)*Pi)/180)+t*Cos(((360/Tn/2)*Pi)/180) 'Y smaller circle center
'little circle end point 2
m=0
n=Pr+(Rd*0.5)
mi=m*Cos(((360/Tn/2)*Pi)/180)-n*Sin(((360/Tn/2)*Pi)/180) 'X smal circle center
ni=m*Sin(((360/Tn/2)*Pi)/180)+n*Cos(((360/Tn/2)*Pi)/180) 'Y smal circle center
'circle big one
a=0 'x1 =
b=Pr 'y1 =
r0=((Rd+Backlash)/2) 'r1 =
'circle 2 little one right
c=si *-1 'x2 =
d=ti 'y2 =
r1=(W/2) 'r0
xp=((c*r0)+(a*r1))/(r0+r1)
yp=((d*r0)+(b*r1))/(r0+r1)
xt56=(((r0^2*(xp-a))+r0*(yp-b)*Sqr((xp-a)^2+(yp-b)^2-r0^2))/((xp-a)^2+(yp-b)^2))+a
yt56=(((r0^2*(yp-b))-r0*(xp-a)*Sqr((xp-a)^2+(yp-b)^2-r0^2))/((xp-a)^2+(yp-b)^2))+b
xt78=(((r1^2*(xp-c))+r1*(yp-d)*Sqr((xp-c)^2+(yp-d)^2-r1^2))/((xp-c)^2+(yp-d)^2))+c
yt78=(((r1^2*(yp-d))-r1*(xp-c)*Sqr((xp-c)^2+(yp-d)^2-r1^2))/((xp-c)^2+(yp-d)^2))+d
dcCreateLine xt56,yt56,xt78,yt78 ' tangent line on right
dcSelectObjInBox xt56+0.2,yt56+0.2,xt78-0.2,yt78-0.2
dcSetSelCopyMode True
dcMirrorSelObjs 0, 0, 0, 2 'mirror line
dcUnSelectAll
'proba duzego na promien
dcCreateCircleEx 0, Pr, -xt56, yt56, xt56, yt56, (Rd+Backlash)/2, (Rd+Backlash)/2, 0, 0
dcCreateCircleEx si, ti, -xt78, yt78, mi, ni, W/2, W/2, 0, 0
dcSelectObjInBox si+0.1, ti, si+0.2,ti+30
dcSetSelCopyMode True
dcMirrorSelObjs 0, 0, 0, 2
dcUnSelectAll
dcSelectObjInBox -1, -1, 1, 1
dcEraseSelObjs
dcUnSelectAll
dcSelectAll
dcSetSelectBase 0, 0
For z=0 to Tn-1
dcRotateSelObjs 360/Tn
dcSetSelCopyMode True
Next z
dcUnSelectAll
dcCreateCircle 0, 0, j/2
dcSetTextParms dcRED, “Arial”, “Normalny”, 0,2,0, 0.1, 0
NL$ = Chr$(13) + Chr$(10)
SprText$ = "Teeth=" + Str$(Tn) + NL$
SprText$ = SprText$ + "Pitch=" + Str$(P) + NL$
SprText$ = SprText$ + "Roller_D=" + Str$(Rd) + NL$
SprText$ = SprText$ + "Pitch_D=" + Str$(Pr*2) + NL$
SprText$ = SprText$ + "Max_D=" + Str$((Pr+(Rd*0.35))*2)
dcCreateText 0, -5, 0, SprText$
End Sub
Posts: 387
Threads: 54
Joined: Apr 2014
Reputation:
8
10-03-2020, 11:21 PM
(This post was last modified: 10-03-2020, 11:41 PM by AlwMVMO.)
I simpified this
Code:
'From >
If k=1 Then
dcSetDrawingUnits dcMillimeters
ElseIf k=2 Then
dcSetDrawingUnits dcInches
ElseIf k>2 Then
k=1
End If
'To this >
If k<>2 Then
dcSetDrawingUnits dcMillimeters
k=1
kText$="MM"
Else
dcSetDrawingUnits dcInches
kText$="Inches"
End If
And change this line
Code:
'From >
dcSetTextParms dcRED, “Arial”, “Normalny”, 0,2,0, 0.1, 0
'To this >
If k=1 Then
dcSetTextParms dcRED, “Arial”, “Normalny”, 0,2,0, 0.1, 0
Else
dcSetTextParms dcRED, “Arial”, “Normalny”, 0,50,0, 0.1, 0
End If
And I added the Units setting to the text
Code:
'From this >
SprText$ = "Teeth=" + Str$(Tn) + NL$
SprText$ = SprText$ + "Pitch=" + Str$(P) + NL$
SprText$ = SprText$ + "Roller_D=" + Str$(Rd) + NL$
SprText$ = SprText$ + "Pitch_D=" + Str$(Pr*2) + NL$
SprText$ = SprText$ + "Max_D=" + Str$((Pr+(Rd*0.35))*2)
'To this >
SprText$ = "Teeth=" + Str$(Tn) + NL$
SprText$ = SprText$ + "Pitch=" + Str$(P) + NL$
SprText$ = SprText$ + "Roller_D=" + Str$(Rd) + NL$
SprText$ = SprText$ + "Pitch_D=" + Str$(Pr*2) + NL$
SprText$ = SprText$ + "Max_D=" + Str$((Pr+(Rd*0.35))*2)+ NL$
SprText$ = SprText$ + "Units=" +kText$
The text was there, it was very small, needed to be 25 times larger for inches.
Posts: 9
Threads: 1
Joined: Jun 2020
Reputation:
0
This line should be change four times
from
to
To use inches this line should be change
from
Code:
dcSelectObjInBox si+0.1, ti, si+0.2,ti+30
to
Code:
dcSelectObjInBox si+0.0001, ti, si+0.0002,ti+30
|
Macro for Sprocket
